# Maintainer: noodlefighter <noodlefighter#gmail.com>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: GONG Chen <chen dot sst at gmail dot com>
# Contributor: 網軍總司令

_pkgname=librime
pkgname=$_pkgname-sbxlm-git
pkgver=1.4.0.r364.g53ca3b7d
_octagramcommit=78dab3a776ee758236b702f535c78f52338fff8d
_luacommit=43877c6da70a772d90517fc816674badcedf930d
pkgrel=1
epoch=1
pkgdesc="Rime input method engine (声笔系列码 GIT version)"
arch=('x86_64')
url="https://github.com/sbxlmdsl/librime"
license=('GPL3')
depends=('boost-libs' 'capnproto' 'opencc' 'yaml-cpp' 'leveldb' 'librime-data' 'lua' 'google-glog' 'marisa')
makedepends=('cmake' 'boost' 'git' 'gtest' 'ninja')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("0001-fix-build.patch"
        "git+https://github.com/sbxlmdsl/librime.git"
        "https://github.com/lotem/librime-octagram/archive/$_octagramcommit/librime-octagram-$_octagramcommit.tar.gz"
        "https://github.com/hchunhui/librime-lua/archive/$_luacommit/librime-lua-$_luacommit.tar.gz")
sha512sums=('SKIP'
            'SKIP'
            'afb19f8e4308fb8c4e4e2675ac54f61c22fdebbc68c87c21e1f53baa2f24c15521c74a70945aaff1ed0c91d7616e3793d5523413260a016df97d2600f7b6e954'
            '005d3462109658acf130b2c68f3ebbb189f8005bc3f4e6015ac44e63ff13f5bf11f5d6a04580ab496e4069023ba227756a0e34e167ac0f246d0ac821309ee855')

prepare() {
  cd $_pkgname
  patch -p1 < ../0001-fix-build.patch
  cd plugins
  ln -sf "$srcdir"/librime-octagram-$_octagramcommit librime-octagram
  ln -sf "$srcdir"/librime-lua-$_luacommit librime-lua
}

pkgver() {
  cd $_pkgname
  git describe --long --tags | sed 's/^rime-//;s/_/./;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $_pkgname
  export CXXFLAGS="$CXXFLAGS -DNDEBUG"
  cmake . -GNinja -Bbuild -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_MERGED_PLUGINS=Off -DENABLE_EXTERNAL_PLUGINS=On
  cmake --build build
}

check() {
  cd $_pkgname/build
  ninja test
}

package() {
  cd $_pkgname/build
  DESTDIR="$pkgdir" ninja install
}